// 1000 Lines
// Paul Bartlett
// 18 Sept 2007

float[][] lineData;
float[]  goal;
float[]  velocity;
float  velScale = 0.0007;
int pad = 10;
int numLines = 1000;
int spaces = numLines+1;

void setup(){
  size(640,480);
  frameRate(50);
  stroke(255);
  strokeWeight(.05);
  smooth();

  // Setup line position & velocity arrays
  lineData = new float[4][numLines];
  goal = new float[numLines];
  velocity = new float[numLines];
  for(int L=0; L<numLines; L++){
    lineData[0][L]=width/spaces+L*width/spaces;
    lineData[1][L]=0;
    lineData[2][L]=width/spaces+L*width/spaces;
    lineData[3][L]=0;
    velocity[L] = 0;
  }
}

void draw(){
  background(0);
  // Set the goal points for each line as the mouse passes 
  for(int m=0; m<numLines; m++){
    if(mouseX < width/spaces+m*width/spaces+pad && mouseX > width/spaces+m*width/spaces-pad){
      goal[m]=mouseY;
    }
  }

  // Animate the lines
  for(int r=0; r<numLines; r++){
    velocity[r] = velScale*(goal[r] - lineData[3][r])*abs(goal[r] - lineData[3][r]);
    lineData[3][r]=lineData[3][r]+velocity[r];
    line(lineData[0][r],lineData[1][r],lineData[2][r],lineData[3][r]);
  }

  if(mousePressed){
    delay(3000);
  }
}