// Alphabet :: Dynamic Word
// Paul Bartlett
// Utilizes code from Golan Levin's alphabet example

PImage ceilFloor;
Letter[] ListOfLetters;
int letterHeight = 125;
int kern = 40;
int margin = 100;
char characters[] = {'s','u','s','p','e','n','d'};
float xoff1 = 0.0;
float xoff2 = 0.0;

float letterData[][] = new float[26][25];
// 5 control points x 2 curves + 0/1/2 for knot
float currentLetter[] = new float[25];

boolean colorsOn = true;


//------------------------------------------------------
void setup(){
  size(480,130);
  ceilFloor = loadImage("ceilfloor.png");

  ListOfLetters = new Letter[characters.length];
  for (int a=0; a<ListOfLetters.length; a++){
    int defXpos = margin+kern*a;
    int defYpos = 2;    
    ListOfLetters[a] = new Letter(defXpos,defYpos,letterHeight); 
  }

  smooth();
  loadLetterData();

}

//------------------------------------------------------
void draw(){
  // Draw static stuff
  if(colorsOn==true){
    background(140);
    //fill(140);
  }
  else{
    background(0);
    fill(255);
  }
  noStroke();
  //rect(margin,margin,7*200*letterHeight/480.0,3*letterHeight);
  fill(0);
  rect(0,0,width,8);
  rect(0,height-9,width,9);
  /*
  fill(0);
  rect(margin+8*kern,margin+3.0*letterHeight-6,
  200*letterHeight/480.0,10.0);
  rect(margin+8*kern,margin+2.0*letterHeight-3,
  200*letterHeight/480.0,10.0);
  */
  xoff1 = xoff1+0.007;
  xoff2 = xoff2+0.01;
  
  for (int b=0; b<ListOfLetters.length; b++){
    int currentChar = characters[b]-97;
    for (int c=0; c<25; c++){    
      currentLetter[c] = letterData[currentChar][c];
    }
    
    ListOfLetters[b].drawBall(currentLetter);
    
    for (int d=1; d<25 ; d=d+2){
      currentLetter[d]=currentLetter[d]+150.0*noise(xoff1+0.1*b)-75.0;
    }
    for (int d=0; d<24 ; d=d+2){
      currentLetter[d]=currentLetter[d]+50.0*noise(xoff2+0.2*b)-25.0;
    }
    ListOfLetters[b].drawCurves(currentLetter);
    ListOfLetters[b].drawBG();
  }

}


//------------------------------------------------------
//------------------------------------------------------
class Letter {
  int xpos, ypos;
  int verticalHeight;
  int letterWidth;

  Letter(int inxpos, int inypos, int inverticalHeight){
    xpos = inxpos;
    ypos = inypos;
    verticalHeight = inverticalHeight;
    letterWidth = 200;

  }


  //------------------------------------------------------  
  void drawBG(){
    pushMatrix();
    translate(xpos,ypos);
    scale(verticalHeight/480.0);
    image(ceilFloor,0,0);
    popMatrix();
  }

  //------------------------------------------------------
  void drawCurves(float[] currentLetter){
    pushMatrix();
    noFill();
    strokeWeight(1.5);
    if(colorsOn==true){
      fill(0,0,0);
      //fill(255);
      noStroke();
    }

    translate(xpos,ypos);
    scale(verticalHeight/480.0);

    // Left curve
    beginShape();  
    curveVertex(200/2-51,-200);
    curveVertex(200/2-51,37);  
    for (int j=0; j<11; j=j+2){
      curveVertex(currentLetter[j]-150,currentLetter[j+1]);
    }
    curveVertex(200/2-52,480-37);
    curveVertex(200/2-52,480+200);  
    endShape();

    // Right curve
    if(colorsOn==true){
      fill(0);
    }
    beginShape();
    curveVertex(200/2+51,-200);
    curveVertex(200/2+51,37);  
    for (int j=12; j<23; j=j+2){
      curveVertex(currentLetter[j]-150,currentLetter[j+1]);
    }
    curveVertex(200/2+58,480-37);
    curveVertex(200/2+58,480+200);  
    endShape();
    popMatrix();

  }

  //------------------------------------------------------
  void drawBall(float[] currentLetter){
    pushMatrix();
    translate(xpos,ypos);
    scale(letterHeight/480.0);
    float s = currentLetter[24];
    float ballYpos = 65+s*88;
    fill(0);
    stroke(0);
    strokeWeight(0.3);
    line(200/2-1,0,200/2-3,ballYpos);
    strokeWeight(1.5);
    ellipse(200/2-5,ballYpos,5+9*s*s,5+9*s*s);
    popMatrix();
  }

}


//------------------------------------------------------
void loadLetterData(){
  String lines[] = loadStrings("letterDataGood.txt"); 
  int t=0;
  for (int i=0; i<lines.length; i++){
    String pieces[] = split(lines[i], '\t');
    for (int u=0; u<24; u++){
      letterData[t][u]=int(pieces[u]);
    }

    // Set knot values
    if(t==4){
      letterData[t][24]=1.8;
    }
    if(t==8 || t==9){
       letterData[t][24]=1.3;
    }
    if(t==0 || t==1 || t==3 || t==6 || t==14 || t==15 || t==16){
      letterData[t][24]=2.1;
    }

    t++;
  }
}